Безиндикаторна търговия и алгоритми

**saxsten** · 16-09-2018 21:29

Здравейте,
Често пъти сме чували мнението че търгуваме по чистата графика ,без намеса на индикатор.
Това не е много вярно
Винаги съществува някакава индикация за вход или изход от пазара
За мен безиндикаторен алгоритъм е онзи алгоритъм ,който не използува стандартните индикатори от ТА и дори сетъпите на Price Action
Цената е псевдоаналогова спрямо времето
Само така ни изглежда ,че тя е непрекъснат аналогов сигнал зависещ от времето/
Цената освен от времето зависи и от броят на излъчените тикове което е друг аргумент за функцията на цената, освен аргумента време.

И така , имаме два вида зависимости при цената:
1.Разглеждаме цената като зависеща от времето ,акумулираме я в барчета от 1,5 15 ,30, 60---- и тн минути и върху тези графики строим техн индикатори.Тука е цялата теория ня ТА.
2.Разглеждаме цената като зависеща от тиковете.
В тази област няма никаква теория развита или разработена
Чисто ново неразработено поле ,бяло петно на картата на форекса
-----------------------------------------------------------------------------
Има и трети безиндикаторен или аз за себе си го наричам микроиндикаторен подход:
Това е когато си изчислите и формирате микро барче с времева дължина под М1.
Дължината на микробарчето е секунди и е по голяма или равна на 1 сек и естествено по малка от 60 сек
След като вече си формирал и изчислил нулевото микробарче нищо не пречи да изчислиш следщото и по следващото го и тн барчета, като на всяко изчислено да присвояваш номер.
След това тези данни се обединяват в масив
Най простото нещо е от този масив да се създаде Микро- МА а създадете ли Микро- МА можете да пресъздадете всички техники от ТА и Price Action на микро ниво.
Това е огромно поле за работа непосилно за силите на сам човек.
Такава технологи също може да се нарече безиндикаторна доколкото не използува стандартните макро-техн индикатори

**saxsten** · 16-09-2018 22:11

По отношение на микро барчетата мога да предложа код за изчислението им но нямам време и възможности да ги обединявам в масив за да правя индикатори
Ако някой мисли че може да се справи с тази задача нека го заяви тука, а аз ще публикувам кода на барчето

#property copyright "robosten"
#property version "1.00"
#property strict
#property link ""
//===========================================

extern int Sek=10;
static datetime H,t= 0;
static double C,F,open,close,high,low;
int ctn;
void start()
{ CoutBar();}

//========================================

int CoutBar()

{ F=0.5*(Ask +Bid);

if (C!=-1.0)
{ H = TimeCurrent() - t; ctn++;

{ if ( H <Sek) high= MathMax(F,C);
if ( H <Sek) low= MathMin(F,C); }

if (H >=Sek){ open = C; close= F; C = F; t = TimeCurrent();}}
else {open = C; close= F; C = F; t = TimeCurrent(); }

return(0); }

**K_W** · 17-09-2018 09:44

Този индикатор ще го градиш върху "плаващи пясъци".

Всеки брокер си настройва платформата както прецени и филтрира и агрегира тикове от доставчиците си на ликвидност, които също варират, отново както си прецени.

Такава идея има смисъл единствено за централизирани индекси и акции и ако си свързан директно към ексчейнджа и получаваш целия му фид. За форекс е безсмислено.

**Mateev** · 17-09-2018 09:59

Първоначално написано от saxsten

По отношение на микро барчетата мога да предложа код за изчислението им но нямам време и възможности да ги обединявам в масив за да правя индикатори
Ако някой мисли че може да се справи с тази задача нека го заяви тука, а аз ще публикувам кода на барчето

В публикувания от тебе код има следните проблеми:
1. Функцията CountBar нищо не прави. Винаги връща нула.
2. Променливата C не е инициализирана, което означава, че още първия ти if ще се издъни. На практика винаги ще връща True.
3. Въртиш някакъв брояч ctn, но на практика няма цикъл. Следователно тази променлива е ненужна. Освен това дори и да имаше цикъл, пак щеше да се издъниш, защото тази променлива също не е инициализирана.
4. Проверките ти за H<Sek винаги ще връщат False, което означава, че high и low ще останат неинициализирани. Дори и да си поправиш if-а, тогава пък high и low ще се инициализират с грешни стойности, защото ги инициализираш с максималната стойност от други две неинициализирани променливи - F и C.
5. Втория if(H>=Sek) ще се изпълни, но променливите open и close ще имат грешни стойности, защото отново им присвояваш неинициализираните променливи F и C.
6. Същото важи и за последния else оператор. В неговото тяло също присвояваш грешни неинициализирани стойност на open и close.
7. Използваш static променливи в глобалното пространство, което е пълна безсмислица, защото те така или иначе са си глобални и по-глобални няма да станат.

**kypa** · 17-09-2018 10:11

Е тука кодец дето що-годе го рисува микро таймфреймът:

Код:

//+--------------------------------------------------------------------------+
//|                                                        i15secProject.mq5 |
//+--------------------------------------------------------------------------+

#property copyright "Copyright 2017, МегаКурец Software Corp."

#property indicator_chart_window

input int Секунди = 15;
input int БройСвещи = 200;
input bool ОтделнаГрафика = true;
input string Шаблон = "muh_template.tpl";

MqlTick muhTickArray[], muhLastBarTickArray[];
MqlRates muhBarArray[], muhLastBarArray[];
double muhTickArrayPrice[],muhLastBarTickArrayPrice[];
datetime starttime, endtime, kyppenttime, kyppentcalctime, startdrawtime, enddrawtime;
int muhMarkFirstTickArray[];

string csname = Symbol()+"."+IntegerToString(Секунди)+"секунди";
long thisChart, nextChart, muhChart;
int endbar;

int OnInit()
  {
   CustomSymbolCreate(csname);
   CustomSymbolSetInteger(csname,SYMBOL_DIGITS,SymbolInfoInteger(Symbol(),SYMBOL_DIGITS));
   SymbolSelect(csname,true);

   if(ОтделнаГрафика==true && ObjectFind(0,"Секундичка")<0)
     {
      ChartOpen(csname,PERIOD_M1);

      thisChart=ChartFirst();
      nextChart=0;
      muhChart=0;

      while(muhChart==0 && nextChart>=0)
        {
         nextChart=ChartNext(thisChart);
         if(ChartSymbol(nextChart)==csname)
           {
            muhChart=nextChart;
            thisChart=ChartID();
            ObjectCreate(thisChart,"Секундичка",OBJ_ARROW_CHECK,0,TimeCurrent(),0.5*(ChartGetDouble(thisChart,CHART_PRICE_MIN)+ChartGetDouble(thisChart,CHART_PRICE_MAX)));
            ObjectSetInteger(thisChart,"Секундичка",OBJPROP_SELECTABLE,true);
           }
         else thisChart=nextChart;
        }

      ChartApplyTemplate(muhChart,Шаблон);
      ChartSetInteger(muhChart,CHART_SCALEFIX,true);
      ChartSetInteger(muhChart,CHART_SHOW_DATE_SCALE,false);
     }

   if(ОтделнаГрафика==false && ObjectFind(0,"Секундичка")<0)
     {
      ObjectCreate(0,"Секундичка",OBJ_CHART,0,0,0);
      ObjectSetInteger(0,"Секундичка",OBJPROP_CORNER,CORNER_LEFT_UPPER);
      ObjectSetInteger(0,"Секундичка",OBJPROP_XDISTANCE,10);
      ObjectSetInteger(0,"Секундичка",OBJPROP_YDISTANCE,25);
      ObjectSetInteger(0,"Секундичка",OBJPROP_XSIZE,400);
      ObjectSetInteger(0,"Секундичка",OBJPROP_YSIZE,300);
      ObjectSetInteger(0,"Секундичка",OBJPROP_DATE_SCALE,0);
      ObjectSetString(0,"Секундичка",OBJPROP_SYMBOL,csname);
      ObjectSetInteger(0,"Секундичка",OBJPROP_PERIOD,PERIOD_M1);
      ObjectSetInteger(0,"Секундичка",OBJPROP_SELECTABLE,true);
     }

   ArrayResize(muhBarArray,БройСвещи);
   ArrayResize(muhLastBarArray,1);
   ArrayResize(muhMarkFirstTickArray,БройСвещи+1);

   return(INIT_SUCCEEDED);
  }

int OnCalculate(const int rates_total,
                const int prev_calculated,
                const datetime &time[],
                const double &open[],
                const double &high[],
                const double &low[],
                const double &close[],
                const long &tick_volume[],
                const long &volume[],
                const int &spread[]
                )
  {
   int n, y, t, k, a;

   kyppenttime=TimeCurrent();
   if(ChartGetInteger(0,CHART_AUTOSCROLL==true)) kyppentcalctime=kyppenttime;
   if(ChartGetInteger(0,CHART_AUTOSCROLL==false))
     {
      endbar=rates_total-ChartGetInteger(0,CHART_FIRST_VISIBLE_BAR)+ChartGetInteger(0,CHART_WIDTH_IN_BARS);
      if(endbar>=rates_total) kyppentcalctime=kyppenttime;
      else kyppentcalctime=time[endbar];
     }

   if(endtime<kyppentcalctime-Секунди || endtime>=kyppentcalctime)
     {
      endtime=Секунди*floor(kyppentcalctime/Секунди);
      starttime=endtime-(Секунди*БройСвещи);
      enddrawtime=Секунди*floor(kyppenttime/Секунди);
      startdrawtime=enddrawtime-(Секунди*БройСвещи);

      if(CopyTicksRange(Symbol(),muhTickArray,COPY_TICKS_ALL,1000*starttime,1000*endtime)<0) Print("да го ева");

      int muhTickArraySize = ArraySize(muhTickArray);
      ArrayResize(muhTickArrayPrice,muhTickArraySize);

      for(k=0; k<muhTickArraySize; k++) muhTickArrayPrice[k]=muhTickArray[k].bid;

      y=1;
      muhMarkFirstTickArray[0]=0;
      muhMarkFirstTickArray[БройСвещи]=muhTickArraySize-1;

      for(n=1; n<muhTickArraySize; n++)
        {
         if(muhTickArray[n].time_msc>=1000*(starttime+y*Секунди))
           {
            muhMarkFirstTickArray[y]=n;
            y++;
           }
        }

      for(t=0; t<БройСвещи; t++)
        {
         muhBarArray[t].open=muhTickArrayPrice[muhMarkFirstTickArray[t]];
         muhBarArray[t].low=muhTickArrayPrice[ArrayMinimum(muhTickArrayPrice,muhMarkFirstTickArray[t],muhMarkFirstTickArray[t+1]-muhMarkFirstTickArray[t])];
         muhBarArray[t].high=muhTickArrayPrice[ArrayMaximum(muhTickArrayPrice,muhMarkFirstTickArray[t],muhMarkFirstTickArray[t+1]-muhMarkFirstTickArray[t])];
         muhBarArray[t].close=muhTickArrayPrice[muhMarkFirstTickArray[t+1]-1]; 
         muhBarArray[t].tick_volume=MathMax(muhMarkFirstTickArray[t+1]-muhMarkFirstTickArray[t],0);
         muhBarArray[t].time=enddrawtime-(БройСвещи-t+1)*60;
        }

      CustomRatesReplace(csname,enddrawtime-БройСвещи*60,enddrawtime,muhBarArray);
     }

   if(kyppentcalctime==kyppenttime)
     {
      CopyTicks(Symbol(),muhLastBarTickArray,COPY_TICKS_ALL,1000*endtime,0);
      
      int muhLastBarTickArraySize = ArraySize(muhLastBarTickArray);
      ArrayResize(muhLastBarTickArrayPrice,muhLastBarTickArraySize);
   
      for(a=0; a<muhLastBarTickArraySize; a++) muhLastBarTickArrayPrice[a]=muhLastBarTickArray[a].bid;
   
      muhLastBarArray[0].open=muhLastBarTickArrayPrice[0];
      muhLastBarArray[0].low=muhLastBarTickArrayPrice[ArrayMinimum(muhLastBarTickArrayPrice,0,0)];
      muhLastBarArray[0].high=muhLastBarTickArrayPrice[ArrayMaximum(muhLastBarTickArrayPrice,0,0)];
      muhLastBarArray[0].close=muhLastBarTickArrayPrice[muhLastBarTickArraySize-1];
      muhLastBarArray[0].tick_volume=muhLastBarTickArraySize;
      muhLastBarArray[0].time=enddrawtime;
   
      CustomRatesReplace(csname,enddrawtime-60,enddrawtime+60,muhLastBarArray);
     }

   return(rates_total);
  }

void OnDeinit(const int reason)
  {
   if(reason!=REASON_RECOMPILE && reason!=REASON_CHARTCHANGE) ObjectDelete(0,"Секундичка");
   SymbolSelect(csname,false);
   CustomSymbolDelete(csname);
   Comment("");
  }

//+--------------------------------------------------------------------------+

Само трябва да му се вържат крайчетата да не връща грешки докато смъкне тиковете (язе откак съм го написал се каня да я свърша таз работа

).
Алтернативно може да се разцъкат таймфреймовете да се инициализира няколко пъти и прескача грешките.

Последните билдове на МетатаТрайдер нещо не иска да се ъпдейтва автоматично графиката, и това евентуално някой ден ще го ремонтирам. Засега трябва да се цъка по секундичката или да се натиска "енд" , че да се обновява.

**saxsten** · 17-09-2018 11:18

Това за пясъците си важи и за нормалните барове Освен това ако поставиш S=300 това е 5 минутен бар ако е S=1440 пък е Н4 и тн.
Та къде са ти "пясъците " да не са ти в главата?
Сега да отговоря на големия и ерудиран програмист
Матеев този код е идея
Като толкова ти пречи инициализий си променливата С=-1 но трябва да знаeщ че тя при всеки тик се самоинициализира и приема стойност С=0
Иначе програмата си работи без значение дали С=-1
Добавих един коментар който показва текущиге стойности на променливите и я пуснах в тестера
Всички променливи се отчитат нормално
--------------------------------------------------------------------------------------------------------
За останалите които са способни да проверят и малко от малко разбират за какво се говори тук пускам един скриин шот с настройките
https://ndox.abv.bg/download?id=64abcb8d4e

Можете сами да се уверите дали работи програмата просто като я пуснете в тестера във визуален режим

А това кода с вградения коментар към него:

#property copyright "robosten"
#property version "1.00"
#property strict
#property link ""
//===========================================

extern int Sek=10;
static datetime H,t= 0;
static double C,F,open,close,high,low; //static double C=-1
int ctn;
void start()
{ CoutBar();}

//========================================

int CoutBar()

{ F=0.5*(Ask +Bid);

if (C!=-1.0)
{ H = TimeCurrent() - t; ctn++;

{ if ( H <Sek) high= MathMax(F,C);
if ( H <Sek) low= MathMin(F,C); }

if (H >=Sek){ open = C; close= F; C = F; t = TimeCurrent();}}
else {open = C; close= F; C = F; t = TimeCurrent(); }

Comment( "ctn= ",ctn," open= ",open," close= ",close," high= ",high," low= ",low," " );

return(0); }

**saxsten** · 17-09-2018 11:54

А ето тук една разработка - индикатор който строи графики по микро барчета с произволна дължина от време
https://www.mql5.com/en/code/10080

**Mateev** · 17-09-2018 13:17

Сакстен наистина има бели петна в познанията си, но проблемът не е в това, а че се мисли за много знаещ. И ако той не го знае нещо, значи никой не го знае. Истината е, че анализа на пазарите на тиково ниво е широко застъпен във всички хедж или HFT фондове. Широко е застъпен и при всички трейдери, измъкнали се от блатото на ръчната търговия и започнали да разработват търговски стратегии. Аз лично всичко анализирам само на тиково ниво. Всички мои концепции пак са само на тиково ниво и разбира се са "безиндикаторни", ако използваме този термин на Сакстен.

Специално за публикувания от него код - ами че той е пълна пародия. Изпълнен е със грешки и не работи дори и само на теория или само като идея. Направих си труда да напиша истински работещ код по идеята на Сахстен, но не заради него, а заради други хора, които той може да заблуди. Моят код е работещ и изтестван, и за него загубих цял един час в писане. При пускането си създава празен масив от барове с достатъчно голям обем, за да побере следващите 7 дена, че и повече. Баровете, които генерира, са с произволна продължителност в секунди - от 1 до колкото си поискате. Тези барове са перфектно подравнени към 01.01.1970 г., когато започва летоброенето на МетаТрадер-a. При затварянето на експерта (или при смяна на таймфрейм, символ и т.н.) баровете се записват на диск в CSV файл и могат да се разгледат на ръка.

Софтуера е далече от съвършенството, но за 1 час толкова. Важното е, че е работещ и изтестван. Който иска, нека да си го усъвършенства. Ето го сорс кода, който както сами забелязвате е на светлинни години по-добър от неработещата подигравка на Скастен. Дори съм му сложил коментари пак заради Сакстен, за да може да научи нещо ново:

Код:

extern int BarPeriod = 10; // Период на бара в секунди
extern int ArrayDays = 7;  // Брой на дните, за които се резервира масив от барове

int StartID; // Начален абсолютен индекс на масива спрямо 01.01.1970 г.
int BarID=0; // Индекс на текущия бар, в който в момента се добавят тикове

MqlRates bars[]; // Масив от барове, започващи от текущия момент и продължаващи ArrayDays дена

//====================================================================
int OnInit() // Инициализация на експерта
 {
   // Определя абсолютния начален индекс на масива от барове спрямо 01.01.1970 г.
   StartID = int(TimeCurrent()/BarPeriod);
   
   // Инициализира масива с вярната дължина   
   ArrayResize(bars, ArrayDays*24*3600/BarPeriod);
   
   // Нулира масива с барове
   ZeroMemory(bars); 
   
   return(INIT_SUCCEEDED); 
 } 
 
//====================================================================
void OnDeinit(const int reason) // Деинициализация на експерта. Записва баровете във файл. 
  {
    // Отваря нов файл за запис. Ако такъв съществува, той се изтрива и презаписва.
    int filehandle=FileOpen("Bars"+Symbol()+".csv",FILE_WRITE|FILE_REWRITE|FILE_CSV); 
    if(filehandle==INVALID_HANDLE)
      {
        Print("File open failed, error ",GetLastError()); 
        return;
      }  
    
    // Записване на Header-а на файла
    FileWrite(filehandle,"Time","Open","High","Low","Close","Volume"); 
    
    // Записване на баровете във файла 
    for(int i=0; i<=BarID; i++) 
      if(bars[i].tick_volume>0) 
        FileWrite(filehandle,
                TimeToStr  (bars[i].time,TIME_DATE|TIME_SECONDS),
                DoubleToStr(bars[i].open, Digits),
                DoubleToStr(bars[i].high, Digits),
                DoubleToStr(bars[i].low,  Digits),
                DoubleToStr(bars[i].close,Digits),
                IntegerToString(bars[i].tick_volume)); 
    
    // Затваряне на файла
    FileClose(filehandle); 
  }
 
//====================================================================
void OnTick() // Стартира се на всеки тик 
 {
   // Чете последния тик и логва грешка, ако има такава.
   MqlTick last_tick;
   if(!SymbolInfoTick(Symbol(),last_tick))Print("SymbolInfoTick() failed, error = ",GetLastError()); 
   
   // Определя индекса на бара, в който трябва да се добави този тик
   BarID = int(TimeCurrent()/BarPeriod) - StartID;
   
   // Ако масива е препълнен, удвоява размера му и нулира новите елементи
   if(ArraySize(bars)<=BarID)
     {
       ArrayResize(bars,BarID*2);
       for(int i=BarID; i<BarID*2; i++) ZeroMemory(bars[i]);
     }  
   
   // Добавя тика във верния бар (верния елемент от масива)
   AddTickToBar(last_tick,bars[BarID]);
   
   Comment("\nBarID=" + BarID + " Ticks in bar=" + bars[BarID].tick_volume);
 }
 
//====================================================================
// Добавя един тик във бар с индекс BarID.
void AddTickToBar(MqlTick &tick, MqlRates &bar)
 {
  // Добавя тика в бара
  if(bar.tick_volume==0) // Изпълнява се само при първия тик на всеки бар
    {
      bar.time   = tick.time/BarPeriod*BarPeriod; 
      bar.open   = tick.bid;
      bar.high   = bar.open;
      bar.low    = bar.open;
      bar.close  = bar.open;
    }
  else // Изпълнява се при всеки следващ тик
    {
      if(bar.high<tick.bid) bar.high=tick.bid;
      if(bar.low >tick.bid) bar.low =tick.bid;
      bar.close = tick.bid;
    }
  bar.tick_volume++; 
 }

**saxsten** · 17-09-2018 22:56

Матееев ти да си чувал за компилатор?
Не знаеш ли че преди да публикуваш нещо което котката е доблякла от някъде у вас и което нещо ти гръмко наричаш код трябва да го пуснеш през компилатора
В твоя случай този така начен код е оплют от компилатора с 23 грешки.
И при това ти си бил най ерудирания програмист
Ами защо тогава кодовете ти ги плюе компилатора?
Сега какво ще правим а ?
Сам ли ще си го оправиш или ще платиш на някого да ти го поправи
Само тези които си генерирал с машинката не са оплюти от компилатора ,защото не си ги правил ти .
Всичките ти кодове такива .
Недовършени недоизпипати , грешни !!
С какви очи съдиш че този или друг код не работел като дори през компилатора не си го пуснал и не си вникнал в идеята .

HTML код:

int OnInit() // Инициализация на експерта
 {
   // Определя абсолютния начален индекс на масива от барове спрямо 01.01.1970 г.
   StartID = int(TimeCurrent()/BarPeriod);
   
   // Инициализира масива с вярната дължина   
   ArrayResize(bars, ArrayDays*24*3600/BarPeriod);
   
   // Нулира масива с барове
   ZeroMemory(bars); 
   
   return(INIT_SUCCEEDED); 
 } 
 
//====================================================================
void OnDeinit(const int reason) // Деинициализация на експерта. Записва баровете във файл. 
  {
    // Отваря нов файл за запис. Ако такъв съществува, той се изтрива и презаписва.
    int filehandle=FileOpen("Bars"+Symbol()+".csv",FILE_WRITE|FILE_REWRITE|FILE_CSV); 
    if(filehandle==INVALID_HANDLE)
      {
        Print("File open failed, error ",GetLastError()); 
        return;
      }  
    
    // Записване на Header-а на файла
    FileWrite(filehandle,"Time","Open","High","Low","Close","Volume"); 
    
    // Записване на баровете във файла 
    for(int i=0; i<=BarID; i++) 
      if(bars[i].tick_volume>0) 
        FileWrite(filehandle,
                TimeToStr  (bars[i].time,TIME_DATE|TIME_SECONDS),
                DoubleToStr(bars[i].open, Digits),
                DoubleToStr(bars[i].high, Digits),
                DoubleToStr(bars[i].low,  Digits),
                DoubleToStr(bars[i].close,Digits),
                IntegerToString(bars[i].tick_volume)); 
    
    // Затваряне на файла
    FileClose(filehandle); 
  }
 
//====================================================================
void OnTick() // Стартира се на всеки тик 
 {
   // Чете последния тик и логва грешка, ако има такава.
   MqlTick last_tick;
   if(!SymbolInfoTick(Symbol(),last_tick))Print("SymbolInfoTick() failed, error = ",GetLastError()); 
   
   // Определя индекса на бара, в който трябва да се добави този тик
   BarID = int(TimeCurrent()/BarPeriod) - StartID;
   
   // Ако масива е препълнен, удвоява размера му и нулира новите елементи
   if(ArraySize(bars)<=BarID)
     {
       ArrayResize(bars,BarID*2);
       for(int i=BarID; i<BarID*2; i++) ZeroMemory(bars[i]);
     }  
   
   // Добавя тика във верния бар (верния елемент от масива)
   AddTickToBar(last_tick,bars[BarID]);
   
   Comment("\nBarID=" + BarID + " Ticks in bar=" + bars[BarID].tick_volume);
 }
 
//====================================================================
// Добавя един тик във бар с индекс BarID.
void AddTickToBar(MqlTick &tick, MqlRates &bar)
 {
  // Добавя тика в бара
  if(bar.tick_volume==0) // Изпълнява се само при първия тик на всеки бар
    {
      bar.time   = tick.time/BarPeriod*BarPeriod; 
      bar.open   = tick.bid;
      bar.high   = bar.open;
      bar.low    = bar.open;
      bar.close  = bar.open;
    }
  else // Изпълнява се при всеки следващ тик
    {
      if(bar.high<tick.bid) bar.high=tick.bid;
      if(bar.low >tick.bid) bar.low =tick.bid;
      bar.close = tick.bid;
    }
  bar.tick_volume++; 
 }

**saxsten** · 18-09-2018 22:58

По повод изцепката на КW че било нямало разработки
Освен индикатора който публикувах по горе ето още един пратен индикатор който хората си продават от повече от 2 години, нищо че било нямало разработки
https://www.mql5.com/ru/market/produ...tab_p_overview
Както се казва :
O sancta simplicitas !

Login

Регистрирайте се в социалните мрежи

Тема: Безиндикаторна търговия и алгоритми

Контрол над темата

Търси тема